Linux双核SMP系统启动流程（Zynq-ARM-CortexA9）

1. THUMB( adr r9, BSYM(1f) ) @ Kernel is always entered in ARM.
2. THUMB( bx r9 ) @ If this is a Thumb-2 kernel,
3. THUMB( .thumb ) @ switch to Thumb now.
4. THUMB(1: )

1. #ifdef CONFIG_THUMB2_KERNEL
3. #if __GNUC__ < 4
4. #error Thumb-2 kernel requires gcc >= 4
5. #endif
7. /* The CPSR bit describing the instruction set (Thumb) */
8. #define PSR_ISETSTATE PSR_T_BIT
10. #define ARM(x...)
11. #define THUMB(x...) x
12. #ifdef __ASSEMBLY__
13. #define W(instr) instr.w
14. #define BSYM(sym) sym + 1
15. #endif
17. #else /* !CONFIG_THUMB2_KERNEL */
19. /* The CPSR bit describing the instruction set (ARM) */
20. #define PSR_ISETSTATE 0
22. #define ARM(x...) x
23. #define THUMB(x...)
24. #ifdef __ASSEMBLY__
25. #define W(instr) instr
26. #define BSYM(sym) sym
27. #endif
29. #endif /* CONFIG_THUMB2_KERNEL */

1. #ifdef CONFIG_THUMB2_KERNEL
2. .macro setmode, mode, reg
3. mov \reg, #\mode
4. msr cpsr_c, \reg
5. .endm
6. #else
7. .macro setmode, mode, reg
8. msr cpsr_c, #\mode
9. .endm
10. #endif

1. /*
2. * Read processor ID register (CP#15, CR0), and look up in the linker-built
3. * supported processor list. Note that we can‘t use the absolute addresses
4. * for the __proc_info lists since we aren‘t running with the MMU on
5. * (and therefore, we are not in the correct address space). We have to
6. * calculate the offset.
7. *
8. * r9 = cpuid
9. * Returns:
10. * r3, r4, r6 corrupted
11. * r5 = proc_info pointer in physical address space
12. * r9 = cpuid (preserved)
13. */
14. __CPUINIT
15. __lookup_processor_type:
16. adr r3, __lookup_processor_type_data   @ R3指向类型数据指针(此处R3是物理地址，可查看反汇编代码，下图3所示)
17. ldmia r3, {r4 - r6}                    @ 读取R3指向地址三个WORD数据到R4,R5,R6
18. sub r3, r3, r4                         @ 物理地址-虚拟地址
19. add r5, r5, r3            @ 将R5的虚拟地址转换成物理地址，R5为类型数据起始地址
20. add r6, r6, r3            @ 将R6的虚拟地址转换成物理地址，R6为类型数据结束地址
21. 1: ldmia r5, {r3, r4}     @ 从R5指向的地址读取两个WORD到R3,R4
22. and r4, r4, r9            @ 获取判断位
23. teq r3, r4                @ 判断本处理器类型是否已找到
24. beq 2f                    @ 若已找到，跳转到2：执行
25. add r5, r5, #PROC_INFO_SZ @ 若未找到，R5指针增到一个类型数据长度
26. cmp r5, r6                @ 是否已查找完所有处理器类型
27. blo 1b
28. mov r5, #0                @ 若未找到本处理器类型信息，返回值R5设置为NULL
29. 2: mov pc, lr
30. ENDPROC(__lookup_processor_type)

1. /*
2. * Look in <asm/procinfo.h> for information about the __proc_info structure.
3. */
4. .align 2
5. .type __lookup_processor_type_data, %object
6. __lookup_processor_type_data:
7. .long .                              @ 当前内存地址（此处为虚拟地址）
   
8. .long __proc_info_begin              @ 处理器类型信息起始地址
   
9. .long __proc_info_end                @ 处理器类型信息结束地址
10. .size __lookup_processor_type_data, . - __lookup_processor_type_data

通过反汇编，我们可以查看内核编译完成后各个数据结构的具体数据。

图3 反汇编代码

__proc_info_begin，__proc_info_end定义位于\linux-xlnx\arch\arm\kernel\vmlinux.lds.S，它用于存储.proc.info.init段的起始地址及结束地址。

1. /*
2. * Note! struct processor is always defined if we‘re
3. * using MULTI_CPU, otherwise this entry is unused,
4. * but still exists.
5. *
6. * NOTE! The following structure is defined by assembly
7. * language, NOT C code. For more information, check:
8. * arch/arm/mm/proc-*.S and arch/arm/kernel/head.S
9. */
10. struct proc_info_list {
11. unsigned int cpu_val;
12. unsigned int cpu_mask;
13. unsigned long __cpu_mm_mmu_flags; /* used by head.S */
14. unsigned long __cpu_io_mmu_flags; /* used by head.S */
15. unsigned long __cpu_flush; /* used by head.S */
16. const char *arch_name;
17. const char *elf_name;
18. unsigned int elf_hwcap;
19. const char *cpu_name;
20. struct processor *proc;
21. struct cpu_tlb_fns *tlb;
22. struct cpu_user_fns *user;
23. struct cpu_cache_fns *cache;
24. };

1. /* Determine validity of the r2 atags pointer. The heuristic requires
2. * that the pointer be aligned, in the first 16k of physical RAM and
3. * that the ATAG_CORE marker is first and present. If CONFIG_OF_FLATTREE
4. * is selected, then it will also accept a dtb pointer. Future revisions
5. * of this function may be more lenient with the physical address and
6. * may also be able to move the ATAGS block if necessary.
7. *
8. * Returns:
9. * r2 either valid atags pointer, valid dtb pointer, or zero
10. * r5, r6 corrupted
11. */
12. __vet_atags:
13. tst r2, #0x3 @ aligned?
14. bne 1f
16. ldr r5, [r2, #0]
17. #ifdef CONFIG_OF_FLATTREE
18. ldr r6, =OF_DT_MAGIC @ is it a DTB?
19. cmp r5, r6
20. beq 2f
21. #endif
22. cmp r5, #ATAG_CORE_SIZE @ is first tag ATAG_CORE?
23. cmpne r5, #ATAG_CORE_SIZE_EMPTY
24. bne 1f
25. ldr r5, [r2, #4]
26. ldr r6, =ATAG_CORE
27. cmp r5, r6
28. bne 1f
30. 2: mov pc, lr @ atag/dtb pointer is ok
32. 1: mov r2, #0
33. mov pc, lr
34. ENDPROC(__vet_atags)