Excel 2003 中如何用VBA 代码访问单元格里的值及操作单元格 - 唐诗宋词的专栏 - 博客频道 - CSDN.NET

在Excel 中编写VBA 代码，最常做的事可能就是操作表单中单元格里的数据。 我这里总结一下如何从VBA 代码中操作单元格的数据。

在VBA 代码中操作单元格需要用到Range 对象，Range 是Excel 库(即Excel.exe文件)提供的一个类，封装了对表单中单元格的所有操作。Range 对象可以是一个单元格，一行单元格，一列单元格，或者四方的连续的单元格范围，甚至是几个单元格范围组合在一起。至于一个具体的Range 对象到底代表什么，就看我们怎么构造它了。(注，Range 类不支持New 操作符，在VBA 代码中声明的Range 变量只能是已有的Range 对象的引用。)

在Excel VBA 中给Range 变量赋值时，等号左边是一个Range 对象的引用名，右边是能返回Range 对象的属性或方法。某些能返回Range 对象的属性体现了(构造)函数的多态性。当然，返回值不一定非要赋给某个引用变量名。

Application，Worksheet 等对象的Range 属性可以返回Range 对象。Range 属性的一种形态是： 
Range(String arg)       传递的参数是个字符串。

例如，Worksheets("Sheet1").Range("A5") 表示“Sheet1”表单上的A5 单元格。 
字符串参数的表达方式是很灵活的，除了像上面的例子表示单一的单元格外，还可以表示一块连续的单元格范围。 
例如，Worksheets("Sheet1").Range("A1:B5") 表示“Sheet1”表单上A1到B5 的一块连续的单元格范围。

此外，字符串参数还可以表示不连续的单元格范围组合在一起。 
例如，Worksheets("Sheet1").Range("A1:A10,C1:C10,E1:E10") 表示“Sheet1”表单上A1到A10，C1到C10，E1到E10 三块单元格范围的集合。

注意：在用字符串表示单元格或单元格范围的地址时，要用A1表示法，不能用R1C1表示法。关于Excel 单元格或单元格范围的几种地址表示法，可以看一下我的另一篇文章。

Range 属性的字符串参数不仅可以表示单元格或单元格范围的地址，如果你在表单里定义了单元格或单元格范围的名称，我们还可以用已定义的名称来访问表单上的单元格。

例如，我们在“Sheet1”表单上选择A1到B5这样一块连续单元格，在“Name Box”里输入Sample，这样就给A1:B5 这个范围起了个名字“Sample”。此时，使用 Worksheets("Sheet1").Range("Sample") 表示的单元格或范围跟使用 Worksheets("Sheet1").Range("A1:B5") 是等价的。

Range 属性也是类的成员，因此，我们可以省略它的限制符，写成：

Range("A1:B5") ，Range("Sample") ，Range("A5") 等等。

当不加对象限制符时，Range 属性返回活动表单上的单元格或范围。如果活动表单不是工作表(Worksheet)的话，比如是Chart Sheet ，这条语句就会出错。加上对象限制符是良好的编程习惯。

Range 属性的另一种形态是： 
Range(Range Cell1, Rang Cell2)        cell1 和 cell2 两个参数都是 Range 对象，表示一块连续单元格中位于对角线两头的单元格，即左上角和右下角的两个单元格。

例如，Range(Range("A1"), Range("C5")) 表示 A1:C5 的单元格范围，跟 Range("A1:C5") 是等价的。所以，我们通常不把 Range 属性这样嵌套起来用，下面讲的Cells 属性经常跟 Range 的这种实现结合在一起用。

Application，Worksheet，Range 等对象的Cells 属性返回的也是 Range 对象，但是Cells 属性返回的是单一的单元格。Excel 库中并没有Cell 这个类，表示单一的单元格和一块单元格范围都并在 Range 这个类中了，就看我们把它初始化成多大。Cells 属性的语法是：

Cells(row, column)        row 表示单元格位于第几行，column 表示单元格位于第几列。

Worksheets(1).Cells(1, 1).Value = 24 ——这行代码把A1 单元格的值设成24

Cells 属性也是类的成员，我们也可以省略它的限制符，默认为活动表单上的单元格。

Cells(2, 1).Formula = "=Sum(B1:B5)"   ——设置活动表单上 A2 单元格的公式

Range("A1")和 Cells(1,1) 都表示单元格A1，但是Cells 属性在编程上有优势，它的行和列参数可以是变量。虽然我们可以通过字符串连接给 Range 属性传递参数，到底是麻烦一些。

Range 属性和Cells 属性结合起来的例子，Range(Cells(1, 1), Cells(5, 3))，表示A1:C5 连续的一块单元格范围，跟 Range("A1:C5") 是等价的。再看个例子：

With Worksheets(1)
    .Range(.Cells(1, 1), .Cells(10, 10)).Borders.LineStyle = xlThick
End With

注意每个Cells 属性前的句点，此时，返回的单元格是第一张工作表上的单元格。如果去掉句点，返回的则是活动表单上的单元格。(第一张工作表不一定是活动表单) 

假设 rowindex 和 columindex 是例程里的两个变量，下面一段代码根据用户输入的行数和列数，从A1单元格一直到 rowindex 和columindex 交叉处的单元格，从1 开始，按行每格递增1填上数字。

rowindex = Val(InputBox("Please enter row number.", , 1))
columnindex = Val(InputBox("Please enter column number.", , 1))
For i = 1 To rowindex
    For j = 1 To columnindex
        Cells(i, j) = (i - 1) * columnindex + j
    Next j
Next i

Cells 属性用在Range 对象时，行数和列数的参照系是Range 对象，也就是说，行和列是相对于Range 对象左上角的单元格开始数的。

例如，Worksheets(1).Range("C5:C10").Cells(2, 1) 指的是第一张表单上的C6 单元格。

Range 对象的 Offset 属性返回当前 Range 对象偏移指定的行数和列数后的一个Range 对象，大小不变，只是位置发生变化。语法：

Offset( row, column)     row 和 column 是行和列的偏移数

Application 和类的方法成员 Union(range1, range2, ...) 可以把多个单元格范围组合在一起作为一个Range 对象。